Article 32courrier du
01 10 2002
Il est très facile de modifier le fichier d'entrée pour l'adapter à la simulation d'une modulation delta.
D'ailleurs, initialement, j'avais simulé et rédigé un article sur la modulation delta. Mais le prototype de mon livre étant trop volumineux, j'ai du faire le choix de retirer le delta et de laisser le sigma delta, plus récent et plus utilisé en électronique (codage des C.D. audio par exemple).
Ci-joint le fichier.cir d'un modulateur delta, et comme les autres, "simulable" avec la version d'évaluation Pspice du CD-ROM.
Ce fichier est un "prêt à simuler" : il suffit, à l'aide de note pad ou équivalent, de faire un copier coller, dans un fichier.cir vierge. Attention de ne pas créer un fichier .cir.txt !
Il présente des points communs avec le fichier du sigma delta : il fait appel aux mêmes composants, mais disposés de façon différente.
Entrée : signal appliqué au noeud 1.
Horloge : au noeud 4.
Sortie comparateur : noeud 3.
Entrée intégrateur : noeud 8.
Sortie intégrateur : noeud 2.
Signal restitué : noeud 9.
Modulateur delta
* Simule un modulateur delta
* fichier modelta.cir
.option itl5=0
.option library expand
.lib eval.lib
* circuit :
.Model int Vswitch (Ron=.1 Roff=10Meg Von=2 Voff=1.6) ; inter parfait
.Model int2 Vswitch (Ron=.1 Roff=10Meg Von=1.6 Voff=2) ; inter parfait
Vplus 10 0 DC 12 ; pour le LM111
Vmoins 11 0 DC -12 ; pour le LM111
Vcc 5 0 DC 5 ; pour la bascule D
Vrefp 12 0 DC 4 ; pour le commutateur
Vrefm 13 0 DC -4 ; pour le commutateur
Vclk 4 0 Pulse (0 5 0 12.5n 12.5n 15.6125u 31.25u) ; horloge 32 kHz
Vin 1 0 sin(0 3 1k 300u 0 0) ; signal d'entree a convertir
X1 1 2 10 11 3 0 LM111 ; comparateur
Rpullup 3 5 10k ; adaptation de la sortie du comparateur
X2 5 3 4 5 6 7 7474 ; bascule D
Sint 12 8 6 0 int ; provoque montee
Sintb 13 8 6 0 int2 ; provoque descente
Einteg 2 0 LAPLACE {V(8)} { 20 /( 1 + s*2e-3 ) } ; integrat. tau = 2ms
Efisor 9 0 LAPLACE {V(2)} { 1 / ( 1 + s*2e-4 + s*s*1e-8 ) } ; filtre
*deuxieme ordre coef d'amort. reduit z = 1 et frequence = 1.6 kHz
.IC v(2)=0 v(8)=0 v(12)=0 v(13)=0
.TRAN 10u 1.6m 0.14m 10u ; simul jusqu'a 1.6ms, stockage et bride 10us
.PROBE
.END
Je vous propose de visualiser :dans une fenêtre ("plot"): V(1), V(2), V(9).
dans une autre : V(8), V(3).
 |
| Modulation delta, démodulation pour voir ce graphe en meilleure résolution. (63 kO) |