Un convertisseur analogique numérique : question et réponse intéressantes

Comprendre l'électronique par la simulation.
par Serge Dusausay            Espace lecteur
                    Courrier

 Article 18

courrier du
20 01 2003

Question : Vous présentez un montage simple qui remplace un convertisseur numérique analogique. Par contre, vous n'en montrez pas qui remplace un convertisseur analogique numérique. Est-ce parce que cela ne peut pas se faire avec une version d'évaluation ? Si par contre cela est possible, pouvez-me dire comment ? Je vous en remercie.

Réponse immédiate :

Effectivement, je n'ai pas mis un article qui aurait pu s'intituler "Un modèle simple de convertisseur analogique numérique".
Mais ce n'est pas parce que le logiciel Pspice fourni dans le CD ROM du livre est une version d'évaluation...
Non, c'est parce qu'il fallait faire un choix (pour éviter un surcoût du livre à cause d'un nombre de pages trop important). Aussi, au moment de la mise en forme finale de l'ouvrage, j'ai renoncé à cet article, après avoir néanmoins creusé le sujet.
Votre email m'a donné l'occasion de rechercher dans mes brouillons (précieusement conservés, car j'ai plein d'autres simulations intéressantes en archive) : je vous donne une réponse plus complète dans une semaine environ.

Vous remarquerez que nous sortons quelque peu de l'esprit de ce "courrier des lecteurs" qui, je le rappelle, est pour donner des explications concernant des passages du livre. Mais votre question intéressera certainement d'autres personnes : c'est pourquoi je donne suite sur ce site.

Réponse suivante :

Bien, voici un résultat mis en forme.
Une façon très simple est de remplacer chaque sortie du CAN par une source de tension commandée, de type tabulée.
Dans l'exemple ci dessous, j'ai réalisé un CAN 5 bits, donc avec 5 sources commandeés.
Le signal d'entrée, ici une rampe permettant de tester toute la dynamique, est une source indépendante.
Par simplicité, j'ai choisi une dynamique 0 16 V, donc un quantum de 0,5 V.

Le CAN ainsi formé est du type "parallèle" (comme les ADC "flash"), car chaque sortie est indépendante et obéit à l'entrée directement. Il n'y a donc pas de signaux d'horloge comme on le voit sur d'autres principes, comme les ADC à approximations successives.

Vous remarquerez que cette façon de procéder ne modélise en rien le temps de conversion du CAN, qui est ici quasi nul. Une simulation 10000 fois plus rapide donne exactement les mêmes chronogrammes, sur une échelle 10000 fois plus petite.
Comme le CNA de l'article 18, il s'agit donc d'un modèle comportemental très simplifié.

Justement, vous remarquerez que j'ai ajouté, dans le montage simulé, un CNA 5 bits, réglé pour retrouver une tension analogique en V(2) l'image du signal d'entré V(1).
Je vous laisse faire le run et afficher V(2) dans la même fenêtre de V(1).

simuler simplement un convertisseur Analogique Numérique (5 bits)

Trace supérieure : signal d'entrée.

Trace inférieure : les 5 sorties numériques.
Les signaux numériques sont de niveau 0 et 4 V, mais présentés ici de façon décalés pour une meilleure lisibilité.

Fichier.cir correspondant :

ADC
* fichier adc5.cir
*
* entree a convertir
Vin 1 0 pwl (0,0 3.2m,16)

* sortie q4 (M.S.B.)
E14 14 0 table { V(1) } ( (0.01,0) (7.99,0) (8.01,4) (15.99,4) ) 

* sortie q3
E13 13 0 table { V(1) } ( 
+ (0.01,0) (3.99,0) (4.01,4) (7.99,4) 
+ (8.01,0) (11.99,0) (12.01,4) (15.99,4) 
+ ) 

* sortie q2
E12 12 0 table { V(1) } ( 
+ (0.01,0) (1.99,0) (2.01,4) (3.99,4) 
+ (4.01,0) (5.99,0) (6.01,4) (7.99,4) 
+ (8.01,0) (9.99,0) (10.01,4) (11.99,4) 
+ (12.01,0) (13.99,0) (14.01,4) (15.99,4) 
+ )  

* sortie q1
E11 11 0 table { V(1) } ( 
+ (0.01,0) (0.99,0) (1.01,4) (1.99,4) 
+ (2.01,0) (2.99,0) (3.01,4) (3.99,4) 
+ (4.01,0) (4.99,0) (5.01,4) (5.99,4) 
+ (6.01,0) (6.99,0) (7.01,4) (7.99,4) 
+ (8.01,0) (8.99,0) (9.01,4) (9.99,4)
+ (10.01,0) (10.99,0) (11.01,4) (11.99,4) 
+ (12.01,0) (12.99,0) (13.01,4) (13.99,4) 
+ (14.01,0) (14.99,0) (15.01,4) (15.99,4)
+ )  

* sortie q0 (lsb)
E10 10 0 table { V(1) } 
+ ( 
+ (0.01,0) (0.49,0) (0.51,4) (0.99,4) 
+ (1.01,0) (1.49,0) (1.51,4) (1.99,4) 
+ (2.01,0) (2.49,0) (2.51,4) (2.99,4)
+ (3.01,0) (3.49,0) (3.51,4) (3.99,4)
+ (4.01,0) (4.49,0) (4.51,4) (4.99,4)
+ (5.01,0) (5.49,0) (5.51,4) (5.99,4)
+ (6.01,0) (6.49,0) (6.51,4) (6.99,4)
+ (7.01,0) (7.49,0) (7.51,4) (7.99,4) 
+ (8.01,0) (8.49,0) (8.51,4) (8.99,4)
+ (9.01,0) (9.49,0) (9.51,4) (9.99,4)
+ (10.01,0) (10.49,0) (10.51,4) (10.99,4)
+ (11.01,0) (11.49,0) (11.51,4) (11.99,4)
+ (12.01,0) (12.49,0) (12.51,4) (12.99,4)
+ (13.01,0) (13.49,0) (13.51,4) (13.99,4)
+ (14.01,0) (14.49,0) (14.51,4) (14.99,4)
+ (15.01,0) (15.49,0) (15.51,4) (15.99,4)
+ )

Edac 2 0 POLY(5) (10,0) (11,0) (12,0) (13,0) (14,0) 
+ 0.25 0.125 0.25 0.5 1 2

.TRAN 1u 3.2m 0m 1u
.probe
.end

retour à l'écran d'accueil, début du site

Comprendre l'électronique par la simulation. par Serge Dusausay Espace lecteur Courrier